Tunneling through a rectangular potential barrier

V=0 for x<0 and x>L
V=V0 for 0<x<L

psileft=Aa Exp[I k x]+Bb Exp[-I k x];
psimiddle=Cc Exp[κ x]+Dd Exp[-κ x];
psiright=Ee Exp[I k x]+Ff Exp[-I k x];

matchingconditions={psileft-psimiddle/.x->0,D[psileft,x]-D[psimiddle,x]/.x->0,psimiddle-psiright/.x->L,D[psimiddle,x]-D[psiright,x]/.x->L}

scatteringproblem={Aa->1,Ff->0}

sols=FullSimplify[Solve[0==matchingconditions/.scatteringproblem,{Bb,Cc,Dd,Ee}]][[1]]

transmissionprob=Ee Conjugate[Ee]/.sols

transmissionprob2=FullSimplify[ComplexExpand[transmissionprob]]

(* The fully simplified result *)
transmissionprob3=1/(1+FullSimplify[Expand[FullSimplify[1/transmissionprob2]-1]])

example1=FullSimplify[transmissionprob3/.k->Sqrt[2m/(h^2)energy]/.κ->Sqrt[2m/(h^2)(V0-energy)]]/.V0->1/.m->1/.h->1/.energy->0.1;

Plot[example1,{L,0,3},PlotRange->All,AxesLabel->{"L","T"}]

example2=FullSimplify[transmissionprob3/.k->Sqrt[2m/(h^2)energy]/.κ->Sqrt[2m/(h^2)(V0-energy)]]/.m->1/.h->1/.L->1/.energy->0.1;

Plot[example2,{V0,0,3},PlotRange->All,AxesLabel->{"V0","T"}]